ALU (算術邏輯單元)

ALU是進行二進制的算術運算(加減乘)

負數用來減法

累加用來乘法

CHIP ALU

{
    IN x[16], y[16], zx, nx, zy, ny, f, no;
    OUT out[16], zr, ng;
    PARTS:
    Mux16(a=x, b=false, sel=zx, out=xval1);         /* if zx then x=0 val=值*/
    Not16(in=xval1, out=notxval);
    Mux16(a=xval1, b=notxval, sel=nx, out=xval);    /* if nx then x=!x */
    Mux16(a=y, b=false, sel=zy, out=yval1);         /* if zy then y=0 */
    Not16(in=yval1, out=notyval);
    Mux16(a=yval1, b=notyval, sel=ny, out=yval);    /* if ny then y=!y */
    Add16(a=xval, b=yval, out=sum);
    And16(a=xval, b=yval, out=and);
    Mux16(a=and, b=sum, sel=f, out=out1);           /* if f then out=x+y else out=x&y */
    Not16(in=out1, out=notout);
    Mux16(a=out1, b=notout, sel=no, out=out2);      /* if no then out=!out */
    Or16Way(in=out2, out=outnonzero);
    Mux(a=true, b=false, sel=outnonzero, out=zr);   /* if out=0 then zr=1 else zr=0 */
    IsNeg16(in=out2, out=neg);
    Mux(a=false, b=true, sel=neg, out=ng);          /* if out<0 then ng=1 else ng=0 */
    Or16(a=out2, b=false, out=out);
}

自行製作兩個工具

CHIP Or16Way

{
    IN in[16];
    OUT out;
    PARTS:
    Or8Way(in=in[0..7], out=out1);
    Or8Way(in=in[8..15], out=out2);
    Or(a=out1, b=out2, out=out);
}

和

CHIP IsNeg16

{
    IN in[16];
    OUT out;
    PARTS:
    And(a=in[15], b=true, out=out);
}

對照

/**
 * The ALU (Arithmetic Logic Unit).
 * Computes one of the following functions:
 * x+y, x-y, y-x, 0, 1, -1, x, y, -x, -y, !x, !y,
 * x+1, y+1, x-1, y-1, x&y, x|y on two 16-bit inputs, 
 * according to 6 input bits denoted zx,nx,zy,ny,f,no.
 * In addition, the ALU computes two 1-bit outputs:
 * if the ALU output == 0, zr is set to 1; otherwise zr is set to 0;
 * if the ALU output < 0, ng is set to 1; otherwise ng is set to 0.
 */

// Implementation: the ALU logic manipulates the x and y inputs
// and operates on the resulting values, as follows:
// if (zx == 1) set x = 0        // 16-bit constant
// if (nx == 1) set x = !x       // bitwise not
// if (zy == 1) set y = 0        // 16-bit constant
// if (ny == 1) set y = !y       // bitwise not
// if (f == 1)  set out = x + y  // integer 2's complement addition
// if (f == 0)  set out = x & y  // bitwise and
// if (no == 1) set out = !out   // bitwise not
// if (out == 0) set zr = 1
// if (out < 0) set ng = 1

CHIP ALU {
    IN  
        x[16], y[16],  // 16-bit inputs        
        zx, // zero the x input?
        nx, // negate the x input?
        zy, // zero the y input?
        ny, // negate the y input?
        f,  // compute out = x + y (if 1) or x & y (if 0)
        no; // negate the out output?

    OUT 
        out[16], // 16-bit output
        zr, // 1 if (out == 0), 0 otherwise
        ng; // 1 if (out < 0),  0 otherwise

    PARTS:
   // Put you code here:

   //zx nx
    Mux16(a=x,b=false,sel=zx,out=x1);                      
    Not16(in=x1,out=notx);
    Mux16(a=x1,b=notx,sel=nx,out=x2);

   //zy ny
    Mux16(a=y,b=false,sel=zy,out=y1);                      
    Not16(in=y1,out=noty);
    Mux16(a=y1,b=noty,sel=ny,out=y2);                            

    Add16(a=x2,b=y2,out=xaddy);
    And16(a=x2,b=y2,out=xandy);

   //f
    Mux16(a=xandy,b=xaddy,sel=f,out=fout);
    Not16(in=fout,out=nfout);  

   //no
    Mux16(a=fout,b=nfout,sel=no,out=noout);

   //zr
    And16(a=noout, b=noout, out[0..7]=outLow, out[8..15]=outHigh); 
    Or8Way(in=outLow,out=o1);
    Or8Way(in=outHigh,out=o2);
    Or(a=o1,b=o2,out=o3);
    Not(in=o3,out=zr);

  //ng 
    And16(a=noout,b=noout,out[15]=ng);
    And16(a=noout,b=noout,out=out);

}